Design of steel beams in houses

NOTE: You can now design Universal Beams on line

There are two values that govern the design of steel beams: (1) the given moment, M, must be less than the beam's moment capacity, PHIM, and (2) limiting the deflection leads to a value for the required moment of inertia, RIX, which must be less than the beam's IX.

We require a database of four values, DESCR, PHIM, IX and KGPM. The database is sorted on self weight SW so that the first satisfactory section found is the lightest. The data is obtained from tables usually provided by the supplier. To set up the database, simply process the next twenty lines. You may, of course, edit the data. If you add or delete a member, please make sure that you add or delete all values with the same index number. Reprocess all lines after editing. However, there is no need to reprocess the lines after the first run if the data is unchanged.

Enter your custom values at lines marked ****, then process all lines. The word "process" means to select (highlight) the relevant text and click the spinning globe in the Engineers' Compendium window. To work with the cue card, you need MATHSERV, which you may download here.

* DESCR = {"125 PFC", "100 PFC", "75 PFC", "125 TFB", "100 TFB"}
* PHIM = {21.0, 11.6, 6.16, 23.1, 9.82}
* IX = {3.97, 1.74, 0.683, 4.34, 1.46}
* KGPM = {11.9, 8.33, 5.92, 13.1, 7.2}
* DESCR = {DESCR, "380 PFC", "300 PFC", "250 PFC", "230 PFC"}
* DESCR = {DESCR, "200 PFC", "180 PFC", "150 PFC"}
* PHIM = {PHIM, 238, 152, 114, 73.3, 59.7, 49, 37}
* IX = {IX, 152, 72.4, 45.1, 26.8, 19.1, 14.1, 8.34}
* KGPM = {KGPM, 55.2, 40.1, 35.5, 25.1, 22.9, 20.9, 17.7}
* DESCR = {DESCR, "150 UB 14.0", "180 UB 16.1", "200 UB 18.2"}
* DESCR = {DESCR, "250 UB 25.7", "310 UB 32.0", "360 UB 44.7"}
* PHIM = {PHIM, 29.3, 39.8, 51.8, 92, 134, 222}
* IX = {IX, 6.66, 10.6, 15.8, 35.4, 63.2, 121}
* KGPM = {KGPM, 14, 16.1, 18.2, 25.7, 32, 44.7}

* convert KGPM to kN/m, SW = KGPM*9.81/1000
* sort on SW, DESCR = statsort(SW, DESCR)
* PHIM = statsort(SW, PHIM)
* IX = statsort(SW, IX)
* SW = statsort(SW)

All units must be consistent, ie. kN and m. Therefore, IX should be converted to m4 (IX=IX/10^6) and E should be expressed in kN/m2 (200*10^6). To avoid having to multiply a very small number with a very large number, we leave IX unconverted at 10^6mm4 and express:

* Modulus of elasiticity E = 200

When the beam carries a uniformly distributed load, W in kN/m, the relevant formulas are:

M = W*MLF*L^2/8 and DEFL = 5*W*DLF*L^4/(384*E*IX), where MLF and DLF are load factors for moment and deflection respectively, L is the span in m, and the product E*IX is in kNm2.

Often the loads are not uniformly distributed but are concentrated point or distributed loads. In these cases, two equivalent uniformly distributed loads can be calculated, one for moment and one for deflection (request the cue card convert.doc).

Our first task is to find the applied loads W and their load factors. We need to refer to AS1170.1 SAA Loading Code Part 1: Dead and live loads and load combinations. Some relevant values are:

Floor live loads:

1.Houses
1.1 General        1.5 kPa or 1.8 kN concentrated
1.2 Balconies      3.0 kPa or 1.5 kN/m along the edge
1.3 Stairs and landings    3.0 kPa or 1.8 kN concentrated
1.4 Parking, drives    3.0 kPa or 13.0 kN concentrated

2.Residential and apartment buildings
2.1 Communal, fixed seating  3.0 kPa
2.2 Communal, open space  5.0 kPa
2.3 Balconies      as for houses
2.4 Bedrooms, private rooms  2.0 kPa

Floor dead loads:

Flooring        .25 (timber) to .50 kPa (fibre cement)
Timber floor joists    FLW^2/25 (FLW is floor load width in m)
Ceiling        .22 to .38 kPa
Concrete slabs      2.50 kPa per 100 thick

Superimposed loads (comprise walls, if any, and roof loads on walls):

Metal roof incl. Ceiling  0.40 kPa
Tiled roof incl. Ceiling  0.90 kPa
Studwalls incl. Lining    0.40 kN/m
2.4 m high brick veneer   4.75 kN/m
2.4 m high rendered brick  5.35 kN/m

Load factors are 1.25 for dead loads and 1.5 for live loads. These apply to moments only, not to deflections. For deflections, dead loads are unfactored (1.0) and live loads may be factored with 0.7.

The following example is a template for a given task. You would enter your values at lines marked ****, then process (see above) the lines. Lines marked * require no input but must be similarly processed or reprocessed if any input is changed.

**** Load width of superimposed roof in m, RLW = 10.3/2 := 5.15
**** Basic roof load in kPa (tiled), BRL = .9
**** Basic wall load in kN/m (stud wall), BWL = .4
* Superimposed dead load in kN/m, SDL[2] = BRL*RLW + BWL := 5.035
* M-factored dead load in kN/m, SDL[1] = 1.25*SDL[2] := 6.2938

NOTE: Do NOT process the next line if there are superimposed loads!
* If NO superimposed loads, process this line SDL[1:2] = 0.0 := 0.

**** Load width of supported floor in m, FLW = 10.3/2 := 5.15
**** Design live load in kPa, DLL = 1.5
* M-factored live load in kN/m, LL[1] = 1.5*DLL*FLW := 11.5875
* D-factored live load in kN/m, LL[2] = .7*DLL*FLW := 5.4075
**** Flooring and ceiling load in kPa, W[1] = .25+.25 := 0.5
* Floor joist dead load in kPa, W[2] = FLW^2/25 := 1.0609
* Unfactored dead load in kN/m, DL[2] = sum(W)*FLW := 8.0386
* M-factored dead load in kN/m, DL[1] = 1.25*DL[2] := 10.0483

With all loads collated and the database set up, enter the span and deflection criteria and process the following equations. You will note that the formula for deflection is modified to return a required value for moment of inertia, RIX.

**** Span of beam in m, L = 4.2
**** Deflection in m, DEFL = min(L/300, 0.020) := 0.014
* Applied moment in kNm, M = (SDL[1]+DL[1]+LL[1])*L^2/8 := 61.5846
* RIX = 5*(SDL[2]+DL[2]+LL[2])*L^4/(DEFL*384*E) := 26.7428

We now loop through the entire database to find the first available section that satisfies both the strength and deflection requirements. Highlight the whole block from For I… to Next I and click the spinning globe:

For I = 1 to endvalid(SW) + 1
  If I > endvalid(SW) then
    print
    Print "No suitable section found in database."
    Exit for
  Elseif M + 1.25*SW[I]*L^2/8 < PHIM[I] and RIX < IX[I] then
    Print
    TL1= SDL[1]+DL[1]+LL[1]+1.25*SW[I]
    TL2= SDL[2]+DL[2]+LL[2]+SW[I]
    Print sprint("At span P(-3) and loads P(-1)/P(-1) kN/m",L,TL1,TL2)
    Print sprint("Section & satisfies:", DESCR[I])
    TMP = M + 1.25*SW[I]*L^2/8
    Print sprint(" M P(-2) < PHIM P(-2) kNm",TMP,PHIM[I])
    Print sprint(" RIX P(-1) < IX P(-1) 10^6 mm4", RIX, IX[I])
    TMP = 5000*(SDL[2]+DL[2]+LL[2]+SW[I])*L^4/(385*E*IX[I])
    Print sprint(" Deflection is P(-1) mm = L/P(0)",TMP,1000*L/TMP)
    TMP = 101.9368*SW[I]*(L+.3)
    Print sprint(" Approximate mass is P(0) kg", TMP)
    Exit for
  End if
Next I

At span 4.200 and loads 28.2/18.7 kN/m
Section 230 PFC satisfies:
M 62.26 < PHIM 73.30 kNm
RIX 26.7 < IX 26.8 10^6 mm4
Deflection is 14.1 mm = L/297
Approximate mass is 113 kg

At span 5.800 and loads 21.3/14.4 kN/m
Section 310 UB 32.0 satisfies:
M 89.73 < PHIM 134.00 kNm
RIX 53.6 < IX 63.2 10^6 mm4
Deflection is 16.7 mm = L/347
Approximate mass is 195 kg

The above six lines are produced by the For-loop for the given case. To avoid cluttering the file, they should be deleted when no longer required. You can see that entering eight design parameters and simply processing all other lines produces the required size and shows the resultant deflection and mass. The cue card has been tested for a wide range of situations and produces accurate results very quickly.

If you changed the data base or wish to keep the last input settings, click File | Save project. If you are new to Engineers' Compendium, first highlight the command and press function key F1.

You may, of course, create another template along similar lines but for different situations, for example steel beams in industrial applications. In this case, the following steps are a useful guide:

  • Step 1: Click File | New project followed by File | Save project as.... Specify a suitable file name, eg. beamdes2.doc.
  • Step 2: Click File | Open cue card and select beamdes.doc~WordPad. You now have two document windows side by side, where beamdes2.doc is the linked document.
  • Step 3: Copy all relevant lines from beamdes.doc and paste into beamdes2.doc, then edit as required, for example increase the number of sections in the data base and set up a different algorithm for collating the loads. NOTE: On some machines, copy & paste can be performed simply by dragging highlighted text from one document to the other.
  • Step 4: Process all lines as instructed. Click File | Save project frequently.
  • Step 5: When all is done, click File | Mark as cue card, select appropriate main and sub categories and provide appropriate descriptions.

Your comments or questions are most welcome - please contact Helmut Schmidhofer at engcomp@pbq.com.au.

The same information is in beamdes.zip (7 kB) or may be read in beamdes.doc (33 kB).